今回は、OfficeのExcel VBAで初心者でも簡単にマクロを作成する方法を紹介します。

Excelのマクロ（VBA）を使ったことがないし、当然プログラミングもしたことがない……
かといって１から勉強を始めるのもハードルが高いなぁ

みみねこ

「マクロの記録」機能で作成したコードを利用すれば、初心者でも簡単にマクロを作成できますよ♪

もちろんプログラミング要素が０とは言いませんが、
ほとんど知識なしでもできてしまう方法ですので、良かったらご参考にしてくださいね。

元となるExcelを作成

まずはマクロを付与する元となるExcelを作成しましょう。

例えば、「健康診断の日程」を社員の人数分印刷するケースです。

以下のように、
まずVLOOKUP関数を利用して「印刷No」を変更するだけで内容を変えられるようにします。
（VLOOKUP関数の使い方については以下を参照してください♪）

【EXCEL】VLOOKUPの使い方（1と0の違い、#N/Aエラー等）

ExcelのVLOOKUP関数について、基本的な使い方として第4引数が「0/FALSE（完全一致）」の場合や「1/TRUE（近似値）」の場合、「#N/A」エラーのIFERROR関数を使った対処方法、使用時の注意事項などサンプルを交えて紹介します♪

nyanblog2222.com

2022.07.18

さて、ここで一つ一つ「印刷No」に値を入れて印刷するを繰り返すのも面倒なので、
From～ToのNoの人へ一括して通知文を印刷したい！とします。

ここで登場するのが処理を自動化させるマクロです。次項から作成方法を説明していきます。

Excelをマクロ形式にする＆開発タブを追加する

前準備としてExcelをマクロ形式にしましょう。

名前を付けて保存する際に、「Excelマクロ有効ブック」を選択して保存します。
こうすることで、ファイルの拡張子が「.xlsm」となり、マクロを保存できるようになります。

次に、もしExcel上部に「開発タブ」が出ていなければ設定してあげましょう。
「開発タブ」からマクロの設定ができます。

「開発」にチェックを入れるとタブが現れます。

「マクロの記録」機能でベースコードを作成

前項までで事前準備もできたため、早速マクロを作成していきましょう。

ただ、いきなりVBAのコードエディタを開き、１からコードを作成……、
なんてことをしてしまうと一気に難易度が高くなってしまうため、
今回はマクロの元となるベースコードを作成するため、Excelの「マクロの記録」という機能を使用します。

「マクロの記録」とは、その名の通りExcelの操作を記録する機能です。

やり方は以下の通り、まず「マクロの記録」をクリックします。

適当にマクロ名を付けて保存します。
（プログラミング言語はアルファベットが基本なので、アルファベットで「動詞＋名詞」のような処理内容がわかる名前がおすすめです）

「OK」を押すと記録が始まるので、記録したい処理を手作業で行います。

今回のケースだと、以下を記録してみましょう。
１．G2の値を変える
２．印刷する

終わったら、記録終了します。

これで記録できました！
マクロボタンをおして、編集を押すと……。

このように、マクロのベースとなるコードができましたね♪

コードを見て、
・G2を選ぶ
・値（2）を入れる
・エンターを押したためG3が選ばれる
・印刷する

という処理内容になっていることがなんとなく分かれば、マクロ作成は難しくありません！
分からなくても、いくつかやっているとなんとなく分かってきますのでご安心を。

また、もし、同じ作業をするだけなら次項のコードの修正は不要なので飛ばしてくださいね♪

コードを適宜修正

前項にてベースコードができましたので、以下のとおり適宜修正していきます。

・G2を選ぶ　→　必要
・値（2）を入れる　→　値にFromToの内容を反映させれるようにする
・エンターを押したためG3が選ばれる　→　G3を選ぶ必要はないため不要
・印刷する　→　必要
◎上記をFromToの間だけ繰り返す！

ここでややこしいプログラミングの知識は一つだけで、「繰り返す」ということです。

繰り返すには「For～Next」というコードを使います。
このコードは、マクロを作るうえではとても重要なもので、
逆にこれだけ覚えていたら、簡易なマクロであればなんとなくの雰囲気だけで作れちゃったりします。

For start To end
     処理
Next

上記の通りstartからendまで、処理を繰り返します。
startの値は一度繰り返すごとに1ずつ増えていき、startの値は処理内で使用することができます。

では、実際に作ってみたコードがこちらです。

Sub PrintFromTo()
　→　マクロ名（関数）
'
' PrintFromTo Macro
'
    Range("G2").Select　→　G2を選ぶ
    
    For i = Range("G5").Value To Range("H5").Value
　　→　iという変数（入れ物）に入れたG5の値からH5の値まで繰り返す
        ActiveCell.FormulaR1C1 = i　→　選んだG2へiの値を入れる
        ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
            IgnorePrintAreas:=False　→　印刷する
    Next　→　iの値を1プラスしてForに戻る

End Sub　→　マクロを終了する

これでコーディングは終了です。初めてでもなんとなく理解できたら幸いです。

できたらコードエディタを右上の×で閉じて、マクロを実行してみましょう。

想定通り、繰り返し印刷できていたら成功です！

（必要であれば）マクロ実行のためのボタン等を作成する

前項のとおりマクロができましたが、毎回マクロの画面を開いて実行と押すのも非効率なので、
必要であればボタン等装飾してみるのもおすすめです。

今回は、ボタンを押すと設定したマクロが実行できるようにしてみましょう。

まず、図形から丸みを帯びた四角のボタンを作成します。

次にボタンを右クリックし、「マクロの登録」を押すと、
以下のように登録画面が出てきますので、作成したマクロを選択しましょう。

これでマクロボタンの作成についても完了です。

どうでしょう、わりと簡単だったなと思っていただけると嬉しいです。
少し難しいと思っても数回やってみると、
「ふ～ん、こんな感じか」と慣れてくると思いますので、是非チャレンジしてみてくださいね！

以上です。
今回の記事が何かの参考になれば幸いです。ありがとうございました♪

投稿 【Excel VBA】初心者でも簡単にマクロを作る方法 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はOfficeのVBAで、If文を一行で記述する方法を紹介します。

If文を一行で記述する方法

If文は通常、以下のように記述します。

If ( 条件式 ) Then
    処理
End If

これを一行で書くと、以下のようなコードになります。
※「End If」を記述しないことで、実現できます

If ( 条件式 ) Then 処理

Else有りでも一行で書けます。

If ( 条件式 ) Then 処理１ Else 処理２

ElseIfを使う場合は一行では書けないようです。

そもそも、一行で書いた方が良い？

If分を一行で書くと見た目がすっきりして、あたかも「かしこいコード」に見えますが、
必ずしも万人にとって読みやすいと思う記述方法ではないと私は思います。

コードは、自分にも他人にも読みやすいものであるべきです。

なので、
一行で書くと読みやすいコードになると思うのであれば、一行で書いた方が良いし、
一行で書くと”もしかしたら”読みにくいコードになるかもしれないと思うのであれば、分けて書いた方が良いと思います。

例えば、こういったケースはどちらが読みやすいでしょうか。

例）ある関数内で、対象フラグが9（エラーフラグ）なら即リターンする

①

If (TargetFlg = 9) Then Exit Function

②

If (TargetFlg = 9)
  Then Exit Function
End If

私なら①の方がスコープが狭まるので読みやすいです。
内容も複雑ではないので、すぐに理解できます。
ただ②も素直なので、どちらを読みやすいと思うかは人によるかもしれませんね。

例）取得した日付が10文字（YYYY/MM/DD）ならそのまま返し、
　　異なれば（YYYYMMDD）、 10文字（YYYY/MM/DD） にして返す関数

①

If (Len(TargetDay) = 10) Then DayFormat = TargetDay Else DayFormat = Left(TargetDay, 4) & "/" & Mid(TargetDay, 5, 2) & "/" & Right(TargetDay, 2)

②

If (Len(TargetDay) = 10) Then
  DayFormat = TargetDay
Else
  DayFormat = Left(TargetDay, 4) & "/" & Mid(TargetDay, 5, 2) & "/" & Right(TargetDay, 2)
End If

私なら②の方が素直で読みやすいです。
①は一行にすると読みづらすぎます！
恐らく他の人からしても②の方が読みやすいのではないでしょうか。
Elseを使う時点で分けた方がいいかもしれませんね。

ということで、判断に迷ったら
「一行で書くことで、自分や他人にとって読みやすくなるか」を考えて記述すると良いと思います。

以上です。
今回の記事が何かの参考になれば幸いです。ありがとうございました♪

投稿 【VBA】If文を一行で記述する方法【Access,Excel】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はAccessVBAでDcount関数を使用したときに、
「実行時エラー ‘2471’: クエリ パラメーターとして指定した式でエラー ‘xxx’ が発生しました。」 とエラーコードがでてしまった場合の対処方法を紹介します。

DCount関数の使い方

対処方法を紹介する前に、簡単に使い方を紹介します。

Dcount関数は、
テーブル等（domain）のフィールド（expr）で値があるレコード、かつ条件（criteria）に合致するレコード数を取得します。

例えば、以下の「社員情報」テーブルで「氏名」フィールドをカウントし、
11000以上の社員NOを取得するときは、このように指定します。

・社員情報

・コード

Sub DCount_OK()

    Dim Tmp As Long
    
    Tmp = DCount("氏名", "社員情報", "社員NO > 11000")
    
    Debug.Print Tmp

End Sub

結果は「2」です。

ここで、例では各要素がダブルコーテーション（”）でくくられていることがわかると思いますが、
Dcount関数を記述する際に一癖あるのが、各要素が文字列であることです。

エラーの原因は？どんな状況で発生する？

私の場合、変数を使って条件を可変にしようとした際にエラーがでました。

前述のDcount関数の使い方にも記述しましたが、
Dcount関数は各要素に文字列を入れる必要があります。

そこで、条件の文字列の中に変数名を入れてしまうと、
「’変数名’という値と比較できないよ！」とエラーが出てしまいます。
なんとなく、「”A > 999″」という書き方ができるため、変数でもいけるのでは？と思ったのが間違いでした。

・コード（誤った例）

Sub DCount_Err()

    Dim Tmp As Long
    
    Dim TestErr As Long
    TestErr = 11000
    
    Tmp = DCount("氏名", "社員情報", "社員NO > TestErr")
    
    Debug.Print Tmp

End Sub

・エラーメッセージ

対処方法

対処方法ですが、
以下のように変数部分を文字列と「＆」で結合させると正しく出力されます。

Sub DCount_Err()

    Dim Tmp As Long
    
    Dim TestErr As Long
    TestErr = 11000
    
    Tmp = DCount("氏名", "社員情報", "社員NO > " & TestErr)
    
    Debug.Print Tmp

End Sub

これで、繰り返し処理などで可変の値が入っても対応することができます。

投稿 【Access】Dcount「クエリ パラメーターとして指定した式でエラー ‘xxx’ が発生しました。」対処方法 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回は、Accessのクエリ等を実行した際に、
「式に未定義関数 ‘xxx’ があります。」とエラーメッセージが出て処理できない場合があります。
このエラーには原因が複数パターン想定されるため、それぞれの対処方法を紹介します。

エラー原因

原因は複数パターンありますが、ざっくり言うと
システムがモジュール内に関数内で使用していないのに使っていると判断しているためです。

以下の通り、うっかりミスからややこしいものもあるため
対処するには一つ一つ順に見ていきましょう。
（上から順に可能性の高いパターンです）

対処方法

以下の正常な状態を一部変更し、エラーパターンを作成していきます。

クエリでの関数呼び出し：「挨拶: CallHello()」

モジュール名：「こんにちは」
関数名：「CallHello()」

Function CallHello() As String

CallHello = "Hello World"

End Function

関数を定義していない、又は誤った関数名を使用している場合

勘違いで呼び出す関数を定義していない、又は誤った関数名を使用している場合、
呼び出すことができずエラーになります。

例えば、
Function CallHello() As String　と宣言しているのに、
CallHallo()で呼び出している場合等

調べるには、一度クエリから呼び出している関数名で、Visual Basic画面にて
プロジェクト内のコード内を検索（ショートカットキー：「Ctrl+F」）してみましょう。
もしなければ、誤っていますのでクエリを変更してください。

関数名とモジュール名が同じ場合

関数名とモジュール名が同じ場合、システム上名称が被ってしまいエラーとなります。

例えば、
Function CallHello() As String　と宣言しており、
モジュール名もCallHelloになっている場合等

この場合、関数名又はモジュール名を変更してください。

ライブラリが参照不可になっている場合

ライブラリが参照不可になっており、
ライブラリ内の関数を使用していた場合、エラーとなります。
パソコンの交換やOS・Officeのバージョンアップでエラーが上がるようになった場合は、
このケースの可能性があります。

この場合、Visual Basic画面にてツールタブから参照設定を開き、参照不可がある場合は、
参照をあらためて追加するか、関数を自前で作成する等やり方を変える必要があります。

関数の宣言でPrivateを使っている場合

関数の宣言でPrivateを使っている場合、
モジュール内からしか呼び出すことができないため、エラーとなります。

Privateはアクセス修飾子と呼ばれ、他にPublic等があります。
以下の通りアクセス修飾子によって参照できる範囲（スコープ）が限られており、
・Private Function：モジュール内のみ参照可
・Public Function：モジュール外から参照可
・Function：暗黙的にPublicとなるため、モジュール外から参照可
となります。

なので、例えば、
Private Function CallHello() As String　と宣言している場合は、
Function CallHello() As String 又は
Public Function CallHello() As String
に変更する必要があります。

関数名に２バイト文字が使用されている場合

関数名に日本語等の２バイト文字が使用されている場合、
VBA上はコンパイルできても対応してはいないので、クエリから呼び出すとエラーとなります。

なので、例えば、
Function 挨拶する() As String　と宣言している場合は、
Function CallHello() As String
に変更する必要があります。
（クエリからの呼び出し側も同様に、CallHello()へ変更）

モジュールが破損している場合

モジュールが破損している場合、呼び出せずエラーとなります。

この場合は、新しくモジュールを作成し、ソースコードをコピーして作り直す必要があります。

投稿 【Access】式に未定義関数 ‘xxx’ があります。[原因,対処方法] は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はAccessのクエリやマクロを使用した際に、
「メモリ不足です。」 と突然エラーコードがでてしまった場合の対処方法を紹介します。

エラーの原因は？どんな状況で発生する？

エラーメッセージが「メモリ」とあるのでパソコンのメモリと勘違いしやすいですが、
原因はクエリやマクロを使用した際に、Accessファイルが2GBを超えてしまうためです。

Accessはファイル全体で最大2GBという制限があります。
私の場合、大規模データを扱うAccessの改修中、
突然「メモリ不足です。」と出て、 以下の対処をすることで解決できました。

＜効果のあったこと＞
・Accessファイルの最適化

＜効果のなかったこと＞
・メモリを8GBから16GBに増設
・仮想メモリを付与
・MaxLocksPerFileというトランザクション処理の最大値を変更
・パソコン再起動
・Accessファイルの修復　等

対処方法

今回のエラーの原因が、Accessファイルが2GBを超過することにあるため、
対処方法は以下のファイルサイズ対策になります。

• Accessファイルの最適化（おすすめ！）
  （手動・自動による最適化）
  Accessファイルを最適化することで、不要な領域を整理する
  メリット：簡単で、今まで通り利用できる
  デメリット：最適化しても容量が2GBを超える場合対応できない
• Accessファイルの分割
  Accessファイルのデータを別のAccessファイルに作り、リンクテーブルで連携する。
  例）AccessAはAテーブル、AccessBはBテーブル。AccessAからBのリンクテーブルを貼る
  メリット：すべてのテーブル容量の合計が2GBを超過しても使用できる
  デメリット：個々のテーブル容量が2GBを超過すると使えない
• DB構築
  SQLServerやPostgresなどDBを構築し、 データはDBからリンクテーブルで利用、編集や更新等はAccessで行う
  メリット：テーブルの容量が2GBを超過しても使用できる
  デメリット：DB構築は少しハードルが高い

ただ、「メモリ不足です。」エラーが出る場合、単純に最適化ができていないことが多いため、 次項からはAccessファイルの最適化だけに絞って説明します。

Accessファイルの最適化（手動）

手動で最適化する方法です。
最適化は数分程度かかることもあるため、ユーザーの都合のいいときに最適化できます。
デメリットは意識的に行わないとならないことです。

方法は、「ファイル」→「情報」から、「データベースの最適化／修復」を選択するだけです。

押すと、最適化が開始され、右下にメッセージが現れます。

Accessファイルの最適化（自動）

自動で最適化する方法です。
Accessファイルを閉じる際に、毎回最適化されるのでユーザーは意識せず最適化できます。
デメリットとしては、毎回最適化に時間がかかることや、
複数ユーザーで頻繁に使用すると破損するリスクがあるため、あまり使用しない方がいいという意見もあります。

方法は、「ファイル」→「Accessのオプション」から、「閉じるときに最適化する」を選択するだけです。

備考：「メモリ不足です。」エラーを再現するには

まず、以下のコードを実行して、2GB弱のデータを作ります。
（コード自体は2GB以上作ろうとするので、処理の途中でAccessが固まる or エラーになります）
コードは、「Microsoft Docs：Access テーブルで操作を実行すると、”ディスク領域またはメモリが足りない” というエラーが発生する」を参考にしています。

Sub CreateBigTable()
　　Dim db As Database, rs As Recordset
　　Dim iCounter As Long, strChar As String
　　Set db = CurrentDb
　　db.Execute "CREATE TABLE BigTable (ID LONG, Field1 TEXT(255), " & _
　　　　"Field2 TEXT(255), Field3 TEXT(255), Field4 TEXT(255))", _
　　　　dbFailOnError
　　Set rs = db.OpenRecordset("BigTable", dbOpenDynaset)
　　iCounter = 0
　　strChar = String(255, " ")
　　While iCounter <= 100000000
　　　　rs.AddNew
　　　　rs!ID = iCounter
　　　　rs!Field1 = strChar
　　　　rs!Field2 = strChar
　　　　rs!Field3 = strChar
　　　　rs!Field4 = strChar
　　　　rs.Update
　　　　iCounter = iCounter + 1
　　Wend
　　MsgBox "Done!"
End Sub

次に、できたテーブルを使用してクエリを作成し、動作させると 「メモリ不足です。」のエラーが再現できます。

投稿 【Access】メモリ不足です。【対処方法・原因】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

AccessのクエリやVBA、SQLでよく使うデータ型変換関数をまとめました。

◇よく使うデータ型変換とは？
Googleで頻繁に検索されているものを主に紹介。
・文字列⇔数値
・文字列⇔日付型
・メモ型→文字列（テキスト型）
・数値→通貨型
その中でもあまり使わないものの説明は省略しています。

※許容範囲の大きい型から小さい型への変換は注意してください！
　エラーなく桁落ちするのでバグと認識しにくいです。

よく使うデータ型変換と使用例

文字列⇔数値

・文字列→数値（整数型）

CInt([項目名])

変換例

・文字列→数値（長整数型）

CLng([項目名])

変換例

・文字列→数値（倍精度浮動小数点型）

CDbl([項目名])

変換例

 参考：文字列→数値においてValやCSng、CDecを使わない理由

・Val
文字列から数値への変換といえば、Val関数もありますが、
文字列に「，」や「￥」、全角文字が含まれると対応できない（値が0になる）ため、あまりおすすめできません。
汎用性を考えるとCDbl([項目名])がおすすめです。

・CSng
単精度浮動小数点型は演算誤差が発生しやすくおすすめできません。
そもそもややこしい分野なのであまり理解せず使用するには危険かと思います。 

・CDec
Access クエリではサポートされていません。

・数値→文字列

CStr([項目名])

変換例

↓　文字列変換

・変換値にNullが含まれる場合

変換元の項目に値が何もない（Null）場合がありますが、
変換関数で出力される値は殆どの場合「#エラー」となってしまいます。
そのため、Nullが想定される場合はNullを指定の値に置換するNz関数を利用します。

Nz([項目名], 置換値）

例）CDbl(Nz([項目名],0))、CStr(Nz([項目名],0))
　　変換前にNullが0に置換されるので、エラーとなりません。

文字列⇔日付型

・文字列→日付型

基本、日付型への変換はCDateを使用しますが、
文字列がどのような形式かでやり方が異なります。

・「YYYY/MM/DD」「YYYY年MM月DD日」「gg年MM月DD日」形式の場合

CDate([項目名])

変換例
「#エラー」となっている箇所については、次項から説明します。

・「YYYYMMDD」形式の場合

CDate(Format([項目名],"@@@@\/@@\/@@"))

または、

DateSerial(Mid([項目名],1,4),Mid([項目名],5,2),Mid([項目名],7,2))

どちらの関数を使っても結果は特に変わらないため好みだと思いますが、
個人的には見やすく、ミスも少なそうなのでFormatを使用するのがおすすめです。

変換例

・「YYYY.MM.DD」形式の場合

CDate(Replace([項目名],".","/"))

変換例

・文字列がNullの場合

IIf(IsNull([項目名]),Null,CDate([項目名]))

NullであればNullを返すので、エラーとなりません。

・日付型→文字列型

CStr([項目名])

変換例

メモ型→文字列（テキスト型）

変換関数はありません。

変換不要で、
・メモ型→文字列
に値の代入（更新）ができます。

数値→通貨型

CCur([項目名])

変換例

参考：データ型変換関数一覧（Microsoft公式サイトより）

データ変換関数は主に以下のような「C」から始まるものがあります。
これらの他にも変換関数はありますが、これだけ知っていたら十分かと思われます。

Microsoft：データ型変換関数より引用

投稿 【Access】データ型変換まとめ【文字列・数値・日付など】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はパソコンの入れ替え後等にVBAマクロ付きのExcelやAccessファイルを使用した際、
「このプロジェクトのコードは、64ビットシステムで使用するために更新する必要があります。
Declareステートメントの確認および更新を行い、
次にDeclareステートメントにPrtSafe 属性を設定してください。」
とエラーコードがでてしまった場合の対処方法を紹介します。

エラーの原因は？どんな状況で発生する？

Office64bitで、
Win32API（32bitのWindows API）を呼び出すと該当のエラーメッセージがでます。
64bitと32bitでは使用できる領域が異なるため、
通常そのまま使うと何かしら問題が発生する場合があります。
よって「使っても良いか」確認の意味も込めたエラーメッセージとなります。

例えば、パソコンの入れ替えやOfficeのバージョンアップで、
Officeが32bitから64bitに変わった際に発生します。

対処方法

対処方法は以下になります。

• Declare文の変更（※１）
  ①PtrSafeを追加
  ②Long型を適宜PtrLong型に変更
• API実行箇所をDeclare文の型に合わせる（引数・戻り値） 

※１　Office64bitでのDeclare文の記述方法は、
以下のとおりMicrosoft公式より公開されていますので、 コピーして使用します。

Microsoft Docs：Win32API_PtrSafe　より、
「Office 2010 ヘルプファイル:64 ビットのサポートが含まれる Win32API_PtrSafe」
へのリンクにとび、
「Office2010Win32API_PtrSafe.exe」をダウンロード・インストール。
インストールすると、
「C:\Office 2010 Developer Resources\Documents\Office2010Win32API_PtrSafe」 に、
Win32API_PtrSafe.TXTが出来上がるので、こちらを開き、該当箇所をコピペする。

なお、Office2010より64bitが新しくできたためOffice2010となっていますが、
他バージョンでも同じように上記のURLからダウンロードします。

コード変更例

例えば、以下のようなコードを記述しているとして、どのように修正するか説明します。
コード内容としては、”user32”というWin32APIを使用し、
「アクティブウィンドウの名前を取得して、出力する」という単純なものです。

Declare Function GetActiveWindow Lib "user32" () As Long
Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Sub GetWindowName()

'アクティブウインドウのハンドル取得
Dim lWindowHwnd As Long
lWindowHwnd = GetActiveWindow()

'バッファを確保
Dim sWindowName As String
sWindowName = String(256, Chr(0))

'アクティブウインドウのウインドウ名取得
Dim lWindowNameLen As Long
lWindowNameLen = GetWindowText(lWindowHwnd, sWindowName, Len(sWindowName))

'イミディエイトに出力
Debug.Print "現在アクテイブウインドウのタイトル名は"
Debug.Print sWindowName
Debug.Print "長さは" + Str(lWindowNameLen) + "です"

End Sub

もちろん、Office32bitではエラーメッセージなしで正常に動きます。

Declare文の変更

まず、Win32API_PtrSafe.TXTを開いて該当の箇所
「GetActiveWindow」「GetWindowTextA」などで検索し、コピペします。

Declare PtrSafe Function GetActiveWindow Lib "user32" () As LongPtr
Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal cch As Long) As Long

Declare文の変更はたったこれだけです♪
注意点は、必ず「Win32API_PtrSafe.TXT」を見てコピペすることです。
バグの元なので全てのLong型をPtrLong型にしないようにしてください。

API実行箇所をDeclare文の型に合わせる（引数・戻り値）

次にAPI実行箇所については、Declare文と睨めっこしながら変更していきます。
今回の場合、GetActiveWindowの戻り値の型であり、
GetWindowTextの第一引数であるlWindowHwndを Long型からLongPtr型に変えます。
命名規則にもよりますが、変数名のルールで型名も考慮しているのであればそちらも変更します。
（ lWindowHwndからlpWindowHwnd）

Private Sub GetWindowName()

'アクティブウインドウのハンドル取得
Dim lpWindowHwndAs LongPtr
lpWindowHwnd = GetActiveWindow()

'バッファを確保
Dim sWindowName As String
sWindowName = String(256, Chr(0))

'アクティブウインドウのウインドウ名取得
Dim lWindowNameLen As Long
lWindowNameLen = GetWindowText(lpWindowHwnd, sWindowName, Len(sWindowName))

'イミディエイトに出力
Debug.Print "現在アクテイブウインドウのタイトル名は"
Debug.Print sWindowName
Debug.Print "長さは" + Str(lWindowNameLen) + "です"

End Sub

他にも元からLong型のものがありますが、Declare文でもLong型なので変更しません。

以上で、VBAのOffice64bit対応は完了です。

補足：PtrSafeやPtrLong型について

簡単に紹介すると以下になります。

• PtrSafe
  Office64bitで実行しても安全であると明示するキーワード
•  

• PtrLong型
  Office32bitではLong型に、Office64bitではLongLong形になる型

このことから、
Office64bitで使えるようにコードを書き換えても、 Office32bitで動くようになっています。

投稿 【対処方法】このプロジェクトのコードは、64ビットシステムで…【Declare,PrtSafe】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

正常に動いていたAccessファイルが、突然 「Microsoft AccessがOLEサーバーまたはActiveXコントロールと通信しているときにエラーが発生しました」 とエラーメッセージが出て使えなくなってしまった場合の対処方法を紹介します。

エラーの原因は？どんな状況で発生する？

エラー原因

調べてみると、対象のAccessファイルのフォーム等に何かしらの不具合があることが原因のようでした。
ただ、「これが原因！」というのは判別しづらいようですね。

どんな状況で発生するか

色々なパターンがあるようですが、
主にAccessファイルを作成したパソコンと異なるパソコンで使用すると起きるようです。

参考として、私は以下の状況でエラーが発生しました。

これは私の想像になりますが、新パソコンのチェック機能の強化により、旧パソコンではチェックされていなかった不具合が表に出てきてしまったのかもしれません。
新しいパソコンだと性能はもちろんセキュリティなども強化され、昔できていたことができなくなることはよくあることだからです。

対処方法・注意事項

対処方法

対処方法は「新しいAccessファイルを作り、元のAccessファイルから全ての情報をインポートする」です。
（説明する際の画像はMicrosoft Office 2010のものですが、手順自体はMicrosoft Office 2019でも同じです）

詳細な手順は以下になります。

（前準備）拡張子がmdbの場合は、accdb変換
必須ではありませんが、mdbはいつか使えなくなる危険性があるのでこのタイミングで変換しておいた方が無難です。
例）CSVインポート.mdb→CSVインポート.accdb
変換した場合はショートカットはもちろん、Accessファイルが他のAccessファイルからリンクテーブルとして参照されている場合、リンク先が変わってしまうためご注意ください。

１．対象のAccessファイルが入っているフォルダと異なるフォルダで右クリックし、 新規作成からMicrosoft Access データベースをクリック

２．新規作成されたAccessファイルを、対象のAccessファイルと同じ名前とする

例）「新規 Microsoft Access データベース.accdb」を作成し、「CSVインポート.accdb」にリネーム

３．２で作成したAccessファイルを開き、外部データタブからAccessデータベースのインポートを選択

４．対象のAccessファイルをクリックして、OKを押すと「オブジェクトのインポート」画面が出るので、オプションをクリック

５．オプションで出てきたチェック項目を全てチェックする

６．全てのタブ（テーブル・クエリ・フォーム・レポート・マクロ・モジュール）ですべて選択をクリックし、OKをクリック

７．Accessファイルを閉じて、元々のAccessファイルのフォルダに移し替える。

※元々のAccessファイルは念のため名前を変えてバックアップとして残しておいてください。

これでAccessファイルの作り直しは完了です。

インポート中に何かしらエラーで取り込めないものがありますが、
恐らく何かしら問題のあるオブジェクトがほとんどですので、
基本不要なものなので気にしなくてもいいかと思います。

ただ、 念のためそのオブジェクトが使われていないかはインポート後に確認して、
必要であれば個別に対象のAccessファイルからコピペしてきてください。

注意事項

上記方法では、VBAのプロジェクト名は引き継がれないので注意してください。
例えば、DAOを使ってテーブル操作をする場合は、Databeseオブジェクトの変数を宣言していたりしますが、その場合、被らないようにプロジェクト名をあえて固有の名前に変えていたりします。

その場合、インポート後に手で直してください。

↓

投稿 【対処方法】Microsoft AccessがOLEサーバーまたはActiveXコントロールと通信しているときにエラーが発生しました は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

VBAには条件分岐の手段の一つとしてSwitch関数やSelect Caseステートメントがありますが、これらの違いや記述方法を紹介します。
C言語やJAVA言語でのswitch文との比較もしてますので、そちらも良かったらどうぞ♪

Switch関数

Switch関数は、ある式（expr）を評価し、Trueであれば値や式（value）を返します。

構文については以下となります。

記述例として、以下を用意しました。
変数の値と特定の値が一致すれば、メッセージを返し、イミディエイトウィンドウに表示します。

' PrintImmediate
' イミディエイトウィンドウにメッセージを表示
Sub PrintImmediate()
    
    Dim sMsg As String
    sMsg = GetMsg_Switch(2)
    
    Debug.Print sMsg
    
End Sub

' GetMsg_Switch(Integer)
' Switch関数を使ってメッセージを取得
Function GetMsg_Switch(iMsgCase As Integer)

    GetMsg_Switch = Switch(iMsgCase = 1, "正常１", iMsgCase = 2, "正常２")

End Function

結果は、「正常２」と表示されます。

Switch関数を使っていく上で知っておきたいポイントは以下になります。
（例については上記の記述例を元にしています。）
・Switch関数を変数に代入しないとコンパイルエラーとなる
例）○GetMsg_Switch = Switch(iMsgCase = 1, “正常１”, iMsgCase = 2, “正常２”)
　　×Switch(iMsgCase = 1, “正常１”, iMsgCase = 2, “正常２”)
・全ての式を評価するため、除算エラー等が起きる式には要注意
例）iMsgCase = 1で、
　　GetMsg_Switch = Switch(iMsgCase = 1, “正常１”, iMsgCase = 2, “正常２”, iMsgCase = 3, 5 / 0)
　　といったコードの場合、「iMsgCase = 3, 5 / 0」部分も評価し除算エラーとなります。
・式がFalseだった場合、Nullを返す
例）iMsgCaseが3の場合、Nullを変数に代入しようとするため、エラーが起きます。

こういったマイナス要素があるため、私は次項の「Select Caseステートメント」がおすすめです。

Select Caseステートメント

Select Caseステートメントは、ある変数の値（testexpression）を複数の値（expressionlist-n）と比較し、一致していれば特定の処理（statements-n）を行います。

構文については以下となります。

記述例として、以下を用意しました。
変数の値と特定の値が一致すれば、メッセージを返し、イミディエイトウィンドウに表示します。

' PrintImmediate
' イミディエイトウィンドウにメッセージを表示
Sub PrintImmediate()
    
    Dim sMsg As String
    sMsg = GetMsg_SelectCase(2)
    
    Debug.Print sMsg
    
End Sub

' GetMsg_SelectCase(Integer)
' SelectCaseステートメントを使ってメッセージを取得
Function GetMsg_SelectCase(iMsgCase As Integer)

       
    Select Case iMsgCase
    Case 1
        GetMsg_SelectCase = "正常１"
    Case 2
        GetMsg_SelectCase = "正常２"
    Case Else
        GetMsg_SelectCase = "異常"
    End Select
        

End Function

結果は、「正常２」と表示されます。
もし、sMsg = GetMsg_SelectCase(3)だった場合は、「異常」と表示されます。

変数に想定外の値が入っていても、Case Elseがあるためエラーを出さずに対応できます。

参考（C言語のswitch文との比較）

参考になりますが、C言語のswitch文は以下のような書き方をします。

int iMsgCase = 2;

switch(iMsgCase){
  case 1:
    printf("正常１¥n");
    break;
  case iMsgCase:
    printf("正常２¥n");
    break;
  default:
    printf("異常¥n");
}

記述内容はほぼSelect Caseステートメントで、内容もほぼ同等の性能です。
逆にSwitch関数とは、名前は似てますが内容は似てません。

以上、今回はSwitch関数やSelect Caseステートメントについて紹介しました。
両者比較すると、マイナスポイントの多いSwitch関数を使うよりは、Select Caseステートメントを使った方がよいのかなと思います。

Switch関数の強みは条件分岐を1行で書けるところかな？と当初考えましたが、いざコードを書いてみると1行に条件を詰め込むのは逆に読みにくいかもと感じました。。

以下まとめです。

本記事で参考にさせていただいたサイト：
Microsoft Doc：Switch 関数
Microsoft Doc：Select Case ステートメント

投稿 【VBA】Switch関数とSelect Caseステートメント【違いや記述方法を簡単に解説】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はAccess等で使われるVBAで、Shift-JIS（SJIS）・UTF-8等、各種文字コードのファイルを読み込む方法を紹介します。
内容としては、OpenステートメントやADODB.Streamを使った手法です。
自作関数のサンプルもつけてますので、是非ご活用ください！
また、同時にダイアログを開いて対象のファイル名を取得する方法も紹介してますので、良かったらそちらもどうぞ。

紹介する手法

まず、本記事の簡単なまとめから♪

共通で使っているテストデータやサブ関数

説明の際に使用するテストデータや、自作関数の中で呼び出しているサブ関数です。
本記事とは内容が離れますので、飛ばしてもらっても大丈夫です。

テストデータ

今回テストとして読み込むcsvファイルは以下を使用します。
（同じ内容で文字コードがShift-JIS・UTF-8のデータを用意）

No	郵便番号	住所	名前
1	859-5326	東京都春日井市向谷町１－６５	ヤマモトコーポレーション株式会社
2	987-2523	千葉県向田市山本町６５８－４４	華井　譲
3	789-0001	千葉県向田市山本町　ジンダ－ビル２F　２０１号	蓮田不動産株式会社
4	653-6567	大阪府大東市浅田８－９９９	株式会社ハッターフ
5	198-3463	鹿児島県薩摩川内市浜本１２３－７７	山本　茂

（サブ関数）ダイアログを開いて対象のファイル名を取得する

ダイアログを開いて対象のファイル名を取得するサブ関数を用意しました。
直接ファイルパスを次項から紹介する関数のコード上に書いてしまっても良かったのですが、それではコピペして使いにくいので。。

内容としては、GetFileName_csvを呼び出すと、ダイアログを開いてcsvファイルのファイル名を取得し、戻り値として返す関数になります。

' GetFileName_csv
' csvファイル名を取得
Function GetFileName_csv()

    'ダイアログを開いてcsvファイルのファイル名を取得
    'Application.FileDialogを使うには、
    '参照設定でMicrosoft Office 1X.0 Object Libraryの追加が必要
    With Application.FileDialog(msoFileDialogOpen)
        .Filters.Clear
        .Filters.Add "csvファイル", "*.csv"
        .AllowMultiSelect = False
        If .Show = True Then
            GetFileName_csv = .SelectedItems(1)
        End If
    End With

End Function

Openステートメントでcsvファイル読み込み（Shift-JISのみ可）

Openステートメントで、csvファイルを読み込む方法です。
Openステートメントでは、文字コードに合わせて対応していくことができないので、Accessのデフォルトの文字コードであるShift-JISでしか正しく読み取りできません。

以下、Openステートメントを使用したcsvファイル読込関数関数です。

' ReadCSVFile_Open
' csvファイル読込関数（Openステートメントを使用）
Sub ReadCSVFile_Open()
    
    'ファイル名取得
    Dim sOpenFileName As String
    sOpenFileName = GetFileName_csv
    If sOpenFileName = "" Then Exit Sub

    'ファイルを読み込んでイミディエイトウィンドウに内容を表示する
    Dim sBuf  As String
    Open sOpenFileName For Input As #1 'ファイルを開いて[#1]という番号で管理
    Do Until EOF(1)
       Line Input #1, sBuf '1行づつバッファへ格納
       Debug.Print sBuf
    Loop
    Close #1
    
End Sub

こちらの関数を使用して、Shift-JISのファイルを読み込んだ結果はこちらです。

ファイル名：SJIS.csv

No  郵便番号    住所    名前
1   859-5326    東京都春日井市向谷町１－６５    ヤマモトコーポレーション株式会社
2   987-2523    千葉県向田市山本町６５８－４４  華井　譲
3   789-0001    千葉県向田市山本町　ジンダ－ビル２F　２０１号   蓮田不動産株式会社
4   653-6567    大阪府大東市浅田８－９９９  株式会社ハッターフ
5   198-3463    鹿児島県薩摩川内市浜本１２３－７７  山本　茂

正確に読み取れてますね。

試しにこの関数を使って、UTF-8も読み取ってみました。

ファイル名：UTF-8.csv

No  驛ｵ萓ｿ逡ｪ蜿ｷ    菴乗園  蜷榊燕
1   859-5326    譚ｱ莠ｬ驛ｽ譏･譌･莠募ｸょ髄隹ｷ逕ｺ・托ｼ搾ｼ厄ｼ・繝､繝槭Δ繝医さ繝ｼ繝昴Ξ繝ｼ繧ｷ繝ｧ繝ｳ譬ｪ蠑丈ｼ夂､ｾ
2   987-2523    蜊・痩逵悟髄逕ｰ蟶ょｱｱ譛ｬ逕ｺ・厄ｼ包ｼ假ｼ搾ｼ費ｼ・闖ｯ莠輔€€隴ｲ
3   789-0001    蜊・痩逵悟髄逕ｰ蟶ょｱｱ譛ｬ逕ｺ縲€繧ｸ繝ｳ繝€・阪ン繝ｫ・巽縲€・抵ｼ撰ｼ大捷 闢ｮ逕ｰ荳榊虚逕｣譬ｪ蠑丈ｼ夂､ｾ
4   653-6567    螟ｧ髦ｪ蠎懷､ｧ譚ｱ蟶よｵ・伐・假ｼ搾ｼ呻ｼ呻ｼ・譬ｪ蠑丈ｼ夂､ｾ繝上ャ繧ｿ繝ｼ繝・
5   198-3463    鮖ｿ蜈仙ｳｶ逵瑚湊鞫ｩ蟾晏・蟶よｵ懈悽・托ｼ抵ｼ難ｼ搾ｼ暦ｼ・螻ｱ譛ｬ縲€闌・

全角が化けてしまっていますね。
前述のとおり、UTF-8を含む他の文字コードには対応していませんので、読み取る必要があれば次項をお使いください。

ADODB.Streamでcsvファイルを読み込む（UTF-8、Shift-JIS他）

ADODB.Streamで、csvファイルを読み込む方法です。
ADODB.Streamでは、UTF-8、Shift-JISを含む各種文字コードに対応しています。

以下、Openステートメントを使用したcsvファイル読込関数関数です。

' ReadCSVFile_ADODB
' csvファイル読込関数（ADODB.Streamを使用）
Sub ReadCSVFile_ADODB()
    
    'ファイル名取得
    Dim sOpenFileName As String
    sOpenFileName = GetFileName_csv
    If sOpenFileName = "" Then Exit Sub

    'ファイルを読み込んでイミディエイトウィンドウに内容を表示する
    Dim sBuf  As String
    With CreateObject("ADODB.Stream")
       .Charset = "UTF-8" 'SJISの場合、"shift_jis"
       .Open
       .LoadFromFile sOpenFileName
        Do Until .EOS
           sBuf = .ReadText(-2) '1行づつバッファへ格納
           Debug.Print sBuf
        Loop
       .Close
    End With
    
End Sub

なお、上記関数をそのままコピペすると、UTF-8に対応した関数になります。
shift_jisに対応させる場合、

.Charset = "UTF-8"

の部分を、

.Charset = "shift_jis"

に書き換えてください。

その他、UTF-8、Shift-JIS以外の文字コードで読み取る場合は、
「レジストリエディタ」の「HKEY_CLASSES_ROOT\MIME\Database\Charset」から確認してください。
レジストリエディタは、
「Windowsマーク」キーと「R」キーを同時押し→ファイル名を指定して実行の画面が出たら、「regedit」と入力してエンターを押すと開くことができます。

それでは、まずshift_jisのファイルを読み込んでみました。

ファイル名：SJIS.csv

No  郵便番号    住所    名前
1   859-5326    東京都春日井市向谷町１－６５    ヤマモトコーポレーション株式会社
2   987-2523    千葉県向田市山本町６５８－４４  華井　譲
3   789-0001    千葉県向田市山本町　ジンダ－ビル２F　２０１号   蓮田不動産株式会社
4   653-6567    大阪府大東市浅田８－９９９  株式会社ハッターフ
5   198-3463    鹿児島県薩摩川内市浜本１２３－７７  山本　茂

正確に読み取れてますね。

ファイル名：UTF-8.csv

No  郵便番号    住所    名前
1   859-5326    東京都春日井市向谷町１－６５    ヤマモトコーポレーション株式会社
2   987-2523    千葉県向田市山本町６５８－４４  華井　譲
3   789-0001    千葉県向田市山本町　ジンダ－ビル２F　２０１号   蓮田不動産株式会社
4   653-6567    大阪府大東市浅田８－９９９  株式会社ハッターフ
5   198-3463    鹿児島県薩摩川内市浜本１２３－７７  山本　茂

こちらも、正しく読み取ることができました♪

以上、今回の記事が参考になれば幸いです。
関連として、もしUTF-8について知りたい！という方はこちらの記事もご覧ください。

【ファイル】UTF-8のBOM付き、BOM無しの違い・確認・作成について

CSVファイルをExcelで確認すると文字化けすることはありませんか。それは文字コードがUTF-8のBOM無しで作成されているからかもしれません。本記事ではUTF-8のBOM付き、BOM無しの違い、確認方法、作成方法についてご紹介しています。

nyanblog2222.com

2022.07.15

投稿 【VBA】Shift-JIS・UTF-8等、各種文字コードのファイル読み込み【コピペで使えるサンプル付き】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

C言語やJAVAなどで欠かせないインクリメントやデクリメントですが、ExcelやAccessなどで使用するVBAでも使えるか、調べてみました。

・インクリメント
変数の値を1増やす演算　例：i++、++i
・デクリメント
変数の値を1減らす演算　例：i－－、－－i

VBAでインクリメントやデクリメントは使えない？

VBAにはインクリメントやデクリメントという概念がなく、使えません。

試しに、i++やi－－と書くと以下のエラーメッセージが出ます。

コンパイルエラー:

修正候補:式

++iやi－－と書くと以下のエラーメッセージが出ます。

コンパイル　エラー:

修正候補: 行番号 または 行ラベル または ステートメント または ステートメントの最後

VBAでインクリメントやデクリメントが使えない理由としては、
VBA（Visual Basic for Applications）はBASICというプログラミング言語がルーツなので、インクリメントやデクリメントが存在するC言語がルーツのプログラミング言語とは、歴史が異なるからです。

代替案について

気になる代替案ですが、残念ながら有効なものはありませんでした。

加算代入演算子や減算代入演算子は？

試してみましたが、インクリメントやデクリメントと似たことができる加算代入演算子や減算代入演算子ではうまくいきませんでした。

（参考）
・加算代入演算子
変数の値に右辺の値を加算する演算　例：i+=1
・減算代入演算子
変数の値に右辺の値を減算する演算　例：i-=1

以下、エラーメッセージです。

コンパイルエラー:

修正候補:式

インクリメントやデクリメントと同様に、C言語がルーツのプログラミング言語で使用できる加算代入演算子や減算代入演算子についても、概念がないようですね。

関数を作ってみるのは？

無理やり捻りだすとするのであらば、インクリメントやデクリメントする関数を作るのはどうでしょう。

例えば、以下の関数「Increment(ByRef)」でインクリメントできます。

'呼び出し元の関数
Public Function TestIncrement()
　Dim i As Int
　i = 0
　～
　Increment i
　～
End Function

'インクリメント用関数
Sub Increment(ByRef i)
　i = i + 1
End Sub

ただこれははっきり言ってしまえば、自己満足なコードです。
あまり分かりやすくなったとは言いづらいですし、作った本人はいいでしょうが、他の人がコードを見たとき読みにくいコードになるでしょうね。。

以上、今回はインクリメントやデクリメントがVBAでも使えるか、また代替案は何かないか調べてみました。
以下がそのまとめです。

そもそもVBAのルーツであるBASICはあくまで初心者向けの言語のため、いくらインクリメントやデクリメントが分かりやすく効率的だからといって、現状でもi = i + 1と1行で処理できるのですから、これ以上知識が必要となる機能追加は望まれないのかもしれませんね。

投稿 【VBA】インクリメントやデクリメントは使える？代替案は？ は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

Accessマクロで関数（VBA）を呼び出した際に出てくる「指定した式に、Microsoft Accessが見つけることができない関数名が含まれています。」の対処方法をいくつか紹介します。
（内容についてはMicrosoft Access 2010で確認）

マクロで呼び出す関数の名称が間違っている

関数名と、マクロで呼び出す関数の名称が異なっているとエラーメッセージが表示されます。

以下の事例だと、関数名が「FileOpen()」なのに対し、マクロでは「FileOpn()」となってしまっています。
この場合、マクロでは関数名と同じ「FileOpen()」を呼び出してください。

関数：

Public Function FileOpen()
　～
End Function

マクロの関数（プロシージャ）呼び出し：

=FileOpn()

関数名に日本語が含まれる

関数名に日本語が含まれているとエラーメッセージが表示されます。

以下の事例だと、関数名が「Fileを開く()」となっており日本語が含まれています。
この場合、日本語は使わず「FileOpen()」などの名前にしてください。

関数：

Public Function Fileを開く()
　～
End Function

関数名とモジュール名が同じ

関数名とモジュール名が同じ場合エラーメッセージが表示されます。

以下の事例だと、関数名が「FileOpen()」に対し、モジュール名も「FileOpen」になってしまっています。
この場合、モジュール名は「ファイルを開く」など関数名と異なる名前にしてください。

関数：

Public Function FileOpen()
　～
End Function

モジュール名：

FileOpen

ちなみに「関数名とマクロ名が同じ」場合はエラーメッセージは出ません。

投稿 【対処方法】指定した式に、Microsoft Accessが見つけることができない関数名が含まれています。 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回はつみたてNISAの資産運用シミュレーションをExcelVBAで作ってみました。
計算方法は金融庁のシミュレーションサイトと同様のものとなります。
よかったら前回の記事もどうぞ♪

【Excel】つみたてNISAシミュレーション（1）【計算方法】

金融庁が公開しているつみたてNISAの資産運用シミュレーションをExcelで作ってみようと思います。金融庁のサイトでは具体的な計算方法はありませんでしたが、試行錯誤しながら調べてみましたので気になる方はどうぞ♪1 つみたてNISAとは2 金融庁の資産運用シミュレーション3 計算方法4 グラフ5 まとめ……。

nyanblog2222.com

2020.07.16

マクロ（VBA）が難易度が高い！と思われる方は一度こちらも見てくださいね♪
練習になるかもしれません。

【Excel VBA】初心者でも簡単にマクロを作る方法

業務効率化したい方必見！OfficeのExcel VBAで"初心者でも簡単に"マクロを作成する方法を紹介しています。知識0でも理解できるようサンプルはもちろん画像たっぷりで説明していますので、是非見て試してみてください♪

nyanblog2222.com

2022.07.10

つみたてNISAシミュレーション作成手順

今回は、
１．EXCELシート作成
２．VBAコード記述
３．マクロ設定
の流れで紹介していきます。

１．EXCELシート作成

まず、入力フォームとして以下を作成します。

ボタンについては「開発」タブ→「挿入」→「ボタン」から作成できます。

２．VBAコード記述

まず、「開発」タブ→「Visual Basic」からVBA記述画面を開きます。

記述していくVBAコードについては以下です。
内容の説明については、コードのコメントを参照ください。

基本的に、前回紹介した計算方法のイメージ通り作成します。

１．計算①　配列に月々の複利計算結果を格納

２．計算②　①の配列から、月々の累計元本・積立額を算出。年毎に配列へ格納

３．出力用配列作成　②の配列を元に出力したい要素を計算し、配列へ格納

４．出力　出力用配列から、それぞれEXCELシートに出力していく
　（３までで出力用データの計算は全て行い、
　　後は４でほぼそのまま出力するだけのイメージ）

■TumitateNisaマクロ

Sub TumitateNisa()

    '積立年数から月数をセット
    Dim TOSHIKIKAN_NEN As Integer
    TOSHIKIKAN_NEN = Range("C2").Value2
    Dim TOSHIKIKAN_NEN_ARRAY As Integer
    TOSHIKIKAN_NEN_ARRAY = TOSHIKIKAN_NEN - 1
    Dim TOSHIKIKAN_TUKI As Integer
    TOSHIKIKAN_TUKI = TOSHIKIKAN_NEN * 12
    Dim TOSHIKIKAN_TUKI_ARRAY As Integer
    TOSHIKIKAN_TUKI_ARRAY = TOSHIKIKAN_TUKI - 1
    
    '月投資額をセット
    Dim TOSHIGAKU_TUKI As Long
    TOSHIGAKU_TUKI = Range("C3").Value2
    
    '利回り（年）から利回り（月）表面金利をセット
    Dim RIMAWAEI_TUKI As Double
    RIMAWAEI_TUKI = 1 + (Range("C4").Value2 / 12 / 100)
    
    '各配列用　年数が最大100年まで（12か月*100年）
    'コードがややこしくなるのと、
    'あまり増えても環境によってはEXCELがフリーズしたりするので
    '今回は動的配列にはしない
    Const MAXARRAY_1200 As Integer = 1200
    
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    ' 計算①　配列に月々の複利計算結果を格納
    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    Dim TumitateArray(MAXARRAY_1200, MAXARRAY_1200) As Double
    For i = 0 To TOSHIKIKAN_TUKI_ARRAY
        
        Dim Tumitate_Tuki As Double
        Tumitate_Tuki = TOSHIGAKU_TUKI
        For j = 0 To TOSHIKIKAN_TUKI_ARRAY
        
            TumitateArray(i, j) = 0
            
            If j >= i Then
                TumitateArray(i, j) = Tumitate_Tuki
                
                Tumitate_Tuki = Tumitate_Tuki * RIMAWAEI_TUKI
            End If
    
        Next j
    
    Next i
    
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    ' 計算②　①の配列から、月々の累計元本・積立額を算出。年毎に配列へ格納
    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    Dim YearSumArray(MAXARRAY_1200, 1) As Double
    Dim GanponSum As Double
    GanponSum = 0
    Dim YearNum As Integer
    YearNum = 0
    For j = 0 To TOSHIKIKAN_TUKI_ARRAY
        
        If j > 0 And j Mod 12 = 0 Then
            YearArrayNum = YearArrayNum + 1
        End If
        
        Dim TumitateSum As Double
        TumitateSum = 0
        For i = 0 To TOSHIKIKAN_TUKI_ARRAY
            TumitateSum = TumitateSum + TumitateArray(i, j)
        Next i
        
        '累計元本
        GanponSum = GanponSum + TOSHIGAKU_TUKI
        YearSumArray(YearArrayNum, 0) = GanponSum
        '累計積立額
        YearSumArray(YearArrayNum, 1) = TumitateSum
    
    Next j
    
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    ' 出力用配列作成　②の配列を元に出力したい要素を計算し、配列へ格納
    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    Dim YearTumitateArray(MAXARRAY_1200, 3) As Double
    For i = 0 To TOSHIKIKAN_NEN_ARRAY
        '累計元本
        YearTumitateArray(i, 0) = YearSumArray(i, 0)
        '累計運用益
        YearTumitateArray(i, 1) = YearSumArray(i, 1) - YearSumArray(i, 0)
        '累計積立額
        YearTumitateArray(i, 2) = YearSumArray(i, 1)
        '累計節税額
        YearTumitateArray(i, 3) = YearTumitateArray(i, 1) * (20.315 / 100)
    
    Next i

    '''''''''''''''''''''''''''''''''''''''''''''''''''
    '
    ' 出力　出力用配列から、それぞれEXCELシートに出力していく
    '
    '''''''''''''''''''''''''''''''''''''''''''''''''''
    '前回のシュミレーション結果をクリアしておく
    Range("B7:F106").Clear
    
    '出力開始位置の一つ上にへカーソル移動
    Range("B6").Select

    'それぞれEXCELシートに出力
    For i = 0 To TOSHIKIKAN_NEN_ARRAY
        
        ActiveCell.Offset(1, 0).Activate
        '年
        ActiveCell.Value2 = i + 1
        '累計元本
        ActiveCell.Offset(0, 1).Value2 = Round(YearTumitateArray(i, 0))
        '累計運用益
        ActiveCell.Offset(0, 2).Value2 = Round(YearTumitateArray(i, 1))
        '累計積立額
        ActiveCell.Offset(0, 3).Value2 = Round(YearTumitateArray(i, 2))
        '累計節税額
        ActiveCell.Offset(0, 4).Value2 = Round(YearTumitateArray(i, 3))
        
    Next i
    
    '罫線を引く
    ActiveCell.CurrentRegion.Select
    Selection.Borders.LineStyle = xlContinuous
        
    '桁区切りする
    Selection.NumberFormatLocal = "#,###"
    
    '最終行の文字を赤色にする
    Selection.Rows(Selection.Rows.Count).EntireRow.Select
    Selection.Font.ColorIndex = 3
    
    'カーソルを年数に戻す
    Range("C2").Select

End Sub

３．マクロ設定

最後に作成したマクロをボタンに登録します。
「右クリック」→「マクロの登録」

マクロを選択して、完了です。

シミュレーション使用方法について

使用方法は簡単です。
「年数」「月投資額」「利回り（年）」を入力して、
「つみたてNISAシミュレーションを開始する」ボタンをクリックするだけ♪

試しに、金融庁のシミュレーションと比べてみましたが、
問題なく同じ結果となりました。
資産運用シミュレーション ： 金融庁

色々と分析してみた

せっかくなので、いくつかのパターンでシミュレーションしてみました♪

利回りが3%と5%どれくらい差が出る？（20年・月20,000円・利回り3%or利回り5%）

2%変わるだけで、運用益が倍変わることが分かります。

[3%の場合]

[5%の場合]

20年間最大額積み立てた場合、いくら貯まる？（20年・月33,333円・利回り5%）

つみたてNISAは年40万円・20年間つみたてが可能です。
そこで仮に平均利回りが5%だった場合、以下の結果となりました。

老後2000万円問題！月5000円積み立てると何年で2000万円貯まる？（60年・月5,000円・利回り5%）

月5,000円ですと、56年で達成可能なようです。
元本と運用益の差から、複利の凄さがよくわかりますね。

万が一、今後経済が不況に陥り、利回り-5%（赤字）だとどれだけ損する？（20年・月20,000円・利回り-5%）

前述の利回り5%と比べると、意外に損失が低いことが分かります。

[-5%の場合]

[5%の場合]

投稿 【Excel】つみたてNISAシミュレーション（2）【VBA】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回は、Access無作為抽出の方法をいくつかご紹介します。

無作為抽出とは、ある母集団から、ランダム（無作為）にサンプルを抽出する方法です。
使う状況でいえば、例えば企業の市場リサーチを目的としたアンケート等がありますね！

Rnd関数を使った方法

Rnd関数は「Rnd(引数)」で呼び出し、0以上1未満の単精度浮動小数点型の乱数（疑似乱数）を返します。今回はこのRnd関数を使用してランダム値を生成し、そしてランダム値を使って並びかえ上位から件数分抜き出し、無作為抽出を実現します。

クエリから引数なしで呼び出す（失敗例）

まずRnd関数を使った失敗例からです。
単純にクエリでRnd関数を引数なしで呼び出せば無作為抽出できそうではありますが……。

テーブル情報

クエリ内容
・下部の赤枠でRnd関数を呼び出し、右上の赤枠部分で上位25件を抽出

結果

このように全レコードに同じ乱数が入ってしまいます。値がすべて同じなので上位25件ではなく1000件すべてが抽出されてしまっていますね。
これはAccessのクエリ最適化の仕様で、引数なしで関数を呼び出した場合、一度しか実行してくれないためです（引数1など固定値でもNG）。
また、Randomizeを実行していないため、乱数ジェネレーター（乱数表）が初期化されません。そのため、もう一度Accessを開きなおし同じクエリを実行した場合、同じ結果になってしまいます。

よって上記をふまえ、以下の方法をご紹介します。

方法１：Rnd関数引数あり、RandomizeのみVBA

先ほどの失敗例を踏まえ、
・Rnd関数に引数を与えることでクエリ最適化を避ける
・Randomizeを実行し、乱数表を初期化する
　こちらは逆に１度呼び出されればいいため、クエリ最適化を利用する
　（何度も呼び出されると件数が多い場合負荷がかかる）
を考慮し、作成しました。

テーブル情報

クエリ内容
・Rnd([社員NO])でランダム値を各レコードに設定
・MyRandomize()で初期化
　抽出条件（Is Null）を加えることで、表示を消しても関数呼び出しができます。

VBA：乱数表初期化

' MyRandomize()
' 乱数ジェネレータ初期化関数
Public Function MyRandomize()
    Randomize
End Function

結果

正常に無作為抽出ができました。
この方法をとる場合は、Randomizeの呼び出し漏れに注意です。レコード件数が少なく処理が遅くなってもよいということであれば、ランダム関数を呼び出す定義関数を作り、その中でRandomizeを呼び出してもいいかもしれませんね。

方法２：VBAで一括ランダム値挿入（マクロ実行）

次に、クエリでRnd関数を呼び出さず、マクロで定義関数を呼び出し、その定義関数内でRandomize＋Rnd関数を呼び出す方法です。
またマクロで実行するため、先日以下の通りご紹介した定義関数で連番もふってます。

【Access】連番の振り方【Dcount以外も紹介】

Accessで連番の振り方を４つ紹介します。①EXCELから連番をコピペする②テーブル定義でオートナンバー型を使う③クエリでDcount関数を使う④マクロ（VBA）で連番用関数を作成する。…Dcount関数の処理速度の遅さに悩んでませんか？連番付番で高速処理したい方は必見です♪

nyanblog2222.com

2020.05.15

テーブル情報
・連番とランダム値項目を用意

クエリ内容

VBA：ランダム数セット
・Randomizeで初期化
・Loopでランダム値を各レコードに設定

' SetRandom(String,String)
' ランダム値をセット
' P1:テーブル名 or クエリ名
' P2:ランダム値項目名
Public Function SetRandom(TargetName As String, TargetField As String)
    
    ' 乱数ジェネレータを初期化
    Randomize
    
    Dim rsTarget As Recordset
    Set rsTarget = CurrentDb.OpenRecordset(TargetName, dbOpenDynaset)
    
    Do Until rsTarget.EOF
        rsTarget.Edit
        rsTarget.Fields(TargetField) = Rnd()
        rsTarget.Update
        rsTarget.MoveNext
    Loop
End Function

結果

正常に無作為抽出ができました。連番もついてますね。
この方法だと確実にRandomizeを呼び出すので、引き継ぎの際もわかりやすいかもしれませんね。ただマクロを使い慣れていないユーザもいるでしょうから、クエリだけでできないところがデメリットです。

テーブル定義のオートナンバー型（ランダム）を使った方法

あまりおすすめしませんが、Rnd関数を使わず、オートナンバー型でランダム値をセットすることもできます。

テーブル１（元テーブル）

クエリ１（追加クエリ）
・後述のテーブル２にレコードを追加

テーブル２
・オートナンバー型のランダム値項目を設定しておく

クエリ１実行結果
この時点で連番が振られています。

クエリ２（件数分抽出）

結果

正常に無作為抽出ができました。
VBAやマクロを使わないということがメリットですが、無理やり組んだ印象が強く、個人的には分かりづらいかなと思います。

投稿 【Access】無作為抽出（ランダム・サンプリング）[Rnd,VBA他] は nyanblog ~にゃんぶろぐ~ に最初に表示されました。

今回は、Accessで連番の振り方をいくつかご紹介します。

大容量レコードに高速付番したい方は、
「４．VBAで連番用関数を作成する」をご確認ください♪

EXCELから連番をコピペする

まず初めに非常にアナログですが、簡単で確実な方法です。
後述するクエリ（DCount関数）で連番を振る方法では件数が多い場合に時間がかかりすぎるため、あえてこのような方法をとっている方もいます。

説明するまでもないかもしれませんが、このように連番用にEXCELを作り、
コピーしてAccessのテーブルに貼り付けます。

メリット：
・Accessの知識が必要ないため、不慣れでも連番を振ることができる。
・クエリの順番通りに連番が振れる。

デメリット：
・手作業のためミスが発生する可能性がある。
・テーブル内容に変更があった場合、対応できない。

使用用途：
一度しか処理せず、再度連番を振る必要ない場合　等

なお、件数が多すぎるとお使いのパソコンやAccessのバージョンによってはペーストする際にエラーがでるようですので、ご注意ください。

テーブル定義でオートナンバー型を使う

テーブルをデザインビューで開き、項目のデータ型を、「オートナンバー型」とするだけなので、最も手軽な振り方です。

このようにデータ型を「オートナンバー型」にするだけで、入力する際、以下のように自動で連番が入力されていきます。

オートナンバー型を使うメリットデメリットですが、以下が考えられます。

メリット：
・手軽で分かりやすい。
・一意（ユニーク）な連番が振られるため、万が一にも重複の心配がない。
・手動で変更できないため、うっかり違う値に変更してしまうことがない。

デメリット：
・連番が振られた後は変更ができない。
・レコードを削除した際に、抜け番が発生する。
・レコード追加時にしか連番が振れない。

この中でも特に、デメリットの一度削除すると抜け番が発生するところが注意点かと思います。
例えば以下のように、レコードを一度入力した後、間違えに気づき修正した場合、抜け番が発生してしまいます。

もちろん連番の変更をしようとしても、以下のエラーが出てしまい、変更もできません。

そんな良くも悪くも融通が利かないオートナンバー型ですが、以下のような使用用途が考えられます。

使用用途：
・絶対に連番が変わってしまうのを避けたい場合
・欠番ができても問題ない場合　等
例）Access内部で使用するデータ紐付け用の主キーID

なお、テーブルをデザインビューで開き、項目の「切り取り」→同じ箇所に「行の挿入」→「貼り付け」をすることで、連番の振り直し自体は可能です。
※１から連番が再度振られるため、連番を振りなおしたことによる影響範囲を検討の上、行ってください。

Dcount関数を使う

クエリで連番を振る際に使用するのがDCount関数を使った方法です。
DCount関数は元々指定した範囲のレコード数をカウントする関数ですが、以下のように指定することで、連番を振ることもできます。

DCount(“*”,”テーブル名”,”[基準項目]<=” & [テーブル名]![基準項目])

指定内容の説明です。
引数１：レコード数をカウント
引数２：テーブル名またはクエリ名
引数３：条件。現在のレコードの[基準項目]以下の[基準項目]の数をカウント

これだけでは分かりにくいので、例を使って見てみましょう。

まず、基準項目を「社員NO」として連番を振るため、データ型は比較可能な「数値型」としています。

連番: DCount(“*”,”T_クエリ”,”[社員NO]<=” & [T_クエリ]![社員NO])

クエリはこのようにDCount関数を使い、設定しました。

結果は以下のとおりです。

Dcount関数を使うメリットデメリット・使用用途ですが、以下が考えられます。

メリット：
・テーブル内容に変更があっても、自動で値が振られ抜け番が発生しない。
・一意（ユニーク）な連番が振られるため、重複の心配がない。

デメリット：
・元々Dcountは別用途で作られた関数のため、不慣れなユーザには判読しづらい。
・基準項目（数値項目等、比較可能な項目）が必要。
・氏名順等、特別な並び順にしたい場合、連番を振ることができない。
・レコード件数が多いと、とにかく重い！
（レコードごとに毎度、基準項目以下のレコードをカウントしにいくため）

使用用途：
・データ入力後に連番が振りたい場合　等

VBAで連番用関数を作成する

少し難易度は上がりますが、VBAで連番用関数を作成し、連番を振る方法です。
VBAを使用し、ユーザ定義関数を作成し、マクロから呼び出します。

VBAについては以下を作成しましたので、コピーしてお使いください。

' InsertRenban(String,String)
' 連番挿入関数
' P1:クエリ名（テーブル名でも可能だが、非推奨）
' P2:連番用項目名
Public Function InsertRenban(TargetName As String, TargetField As String)
    Dim rsTarget As Recordset
    Set rsTarget = CurrentDb.OpenRecordset(TargetName, dbOpenDynaset)
    
    Dim iRecordCnt As Long
    
    'レコード毎に"+1"し、終端まで読み込み
    Do Until rsTarget.EOF
        lRecordCnt = lRecordCnt + 1
        
        rsTarget.Edit
        rsTarget.Fields(TargetField) = lRecordCnt
        rsTarget.Update
        rsTarget.MoveNext
    Loop
End Function

では、例を使ってご紹介します。
まずテーブルは以下です。新しく連番をつける場合は、テーブル定義で「連番」項目を追加してください。

次にクエリを用意し、並び順を確定させます。
※テーブルの順はAccessが独自にソートしているだけなので、今回のVBAを使い連番を振る場合、この工程が重要です。

実行マクロについては、以下としました。

InsertRenban(“Q_定義関数”,”連番”)

実行結果は以下となりました。

メリットデメリット・使用用途については以下となります。
個人的には、クエリを使うのであればこちらをおすすめします。

メリット：
・テーブル内容に変更があっても、自動で値が振られ抜け番が発生しない。
・一意（ユニーク）な連番が振られるため、重複の心配がない。
・クエリに比べ、レコード件数が多くても処理が速い！
・連番はクエリの並び順に左右されるため、基準項目は不要

デメリット：
・マクロ、VBAを使うのでAccess初心者には取っつきにくい。

使用用途：
・データ入力後に連番が振りたい場合　等

投稿 【Access】連番の振り方【Dcount以外も紹介】 は nyanblog ~にゃんぶろぐ~ に最初に表示されました。